Add original-firmware Sound & Speech, four configurable Multi-Pak sockets, bounded per-slot ROM allocation and a nine-page menu organized around devices and media. Repair inherited clock/reset/CPU-memory/video paths and add explicit conditional external-I/O timing contracts. Preserve native Main startup-file ordering, saved layouts, stock-core separation and the coco3plus media profile. Provide native Windows tool downloads, pinned ToolShed ROM assembly, fresh Quartus builds, functional and fitted timing checks, reviewed release packaging and passwordless SSH installation with backups. Retain original component notices, document contribution copyright and keep SSC ROM inputs outside Git. Validation: Quartus17.0.2 Build602 seed5, zero errors; 15 functional jobs, 368 both-corner timing scopes and eight tooling-integrity checks pass. The renamed build reaches Disk BASIC, PRINT1+1 returns2 and SSC loads ready. Physical cold power cycling and conditional board-delay assumptions remain separate. Full original upstream histories are preserved before this single consolidated implementation commit.
112 lines
2.9 KiB
Verilog
112 lines
2.9 KiB
Verilog
// Original Coco 3 Plus contributions: Copyright (c) 2026 Brian K. Holman.
|
|
// Original component notices/terms retained; see COPYRIGHT.md and LICENSING.md.
|
|
|
|
module i2c
|
|
(
|
|
input CLK,
|
|
|
|
input START,
|
|
input READ,
|
|
input [6:0] I2C_ADDR,
|
|
input I2C_WLEN, // 0 - one byte, 1 - two bytes
|
|
input [7:0] I2C_WDATA1,
|
|
input [7:0] I2C_WDATA2,
|
|
output [7:0] I2C_RDATA,
|
|
output reg END = 1,
|
|
output reg ACK = 0,
|
|
|
|
//I2C bus
|
|
output I2C_SCL,
|
|
inout I2C_SDA
|
|
);
|
|
|
|
|
|
// Clock Setting
|
|
parameter CLK_Freq = 50_000_000; // 50 MHz
|
|
parameter I2C_Freq = 400_000; // 400 KHz
|
|
|
|
localparam I2C_FreqX2 = I2C_Freq*2;
|
|
// Wait >=400 ns after the generated falling edge before changing SDA.
|
|
// This covers a fast-mode 300 ns SCL fall plus 40 ns fabric skew; the
|
|
// former four-clock (80 ns at 50 MHz) pipeline could change data while the
|
|
// external SCL was still high. Minimum two stages keeps the slice valid.
|
|
localparam SDA_DELAY_STAGES = (CLK_Freq >= 5_000_000) ?
|
|
(CLK_Freq + 2_500_000 - 1)/2_500_000 : 2;
|
|
|
|
reg I2C_CLOCK;
|
|
reg [31:0] cnt;
|
|
wire [31:0] cnt_next = cnt + I2C_FreqX2;
|
|
|
|
always @(posedge CLK) begin
|
|
cnt <= cnt_next;
|
|
if(cnt_next >= CLK_Freq) begin
|
|
cnt <= cnt_next - CLK_Freq;
|
|
I2C_CLOCK <= ~I2C_CLOCK;
|
|
end
|
|
end
|
|
|
|
assign I2C_SCL = (SCLK | I2C_CLOCK) ? 1'bZ : 1'b0;
|
|
assign I2C_SDA = SDO[SDA_DELAY_STAGES-1] ? 1'bz : 1'b0;
|
|
|
|
reg SCLK;
|
|
reg [SDA_DELAY_STAGES-1:0] SDO;
|
|
reg [0:7] rdata;
|
|
|
|
reg [5:0] SD_COUNTER;
|
|
reg [0:31] SD;
|
|
|
|
initial begin
|
|
SD_COUNTER = 'b111111;
|
|
SD = 'hFFFF;
|
|
SCLK = 1;
|
|
SDO = {SDA_DELAY_STAGES{1'b1}};
|
|
end
|
|
|
|
assign I2C_RDATA = rdata;
|
|
|
|
always @(posedge CLK) begin
|
|
reg old_clk;
|
|
reg old_st;
|
|
reg rd,len;
|
|
|
|
old_clk <= I2C_CLOCK;
|
|
old_st <= START;
|
|
|
|
// delay to make sure SDA changed while SCL is stabilized at low
|
|
if(old_clk && ~I2C_CLOCK && ~SD_COUNTER[5]) SDO[0] <= SD[SD_COUNTER[4:0]];
|
|
SDO[SDA_DELAY_STAGES-1:1] <= SDO[SDA_DELAY_STAGES-2:0];
|
|
|
|
if(~old_st && START) begin
|
|
SCLK <= 1;
|
|
SDO <= {SDA_DELAY_STAGES{1'b1}};
|
|
ACK <= 0;
|
|
END <= 0;
|
|
rd <= READ;
|
|
len <= I2C_WLEN;
|
|
if(READ) SD <= {2'b10, I2C_ADDR, 1'b1, 1'b1, 8'b11111111, 1'b1, 3'b011, 9'b111111111};
|
|
else SD <= {2'b10, I2C_ADDR, 1'b0, 1'b1, I2C_WDATA1, 1'b1, I2C_WDATA2, 4'b1011};
|
|
SD_COUNTER <= 0;
|
|
end else begin
|
|
if(~old_clk && I2C_CLOCK && ~&SD_COUNTER) begin
|
|
SD_COUNTER <= SD_COUNTER + 6'd1;
|
|
case(SD_COUNTER)
|
|
01: SCLK <= 0;
|
|
10: ACK <= ACK | I2C_SDA;
|
|
19: if(~rd) begin
|
|
ACK <= ACK | I2C_SDA;
|
|
if(~len) SD_COUNTER <= 29;
|
|
end
|
|
20: if(rd) SCLK <= 1;
|
|
23: if(rd) END <= 1;
|
|
28: if(~rd) ACK <= ACK | I2C_SDA;
|
|
29: if(~rd) SCLK <= 1;
|
|
32: if(~rd) END <= 1;
|
|
endcase
|
|
|
|
if(SD_COUNTER >= 11 && SD_COUNTER <= 18) rdata[SD_COUNTER[4:0]-11] <= I2C_SDA;
|
|
end
|
|
end
|
|
end
|
|
|
|
endmodule
|